
   1 .
   2 .LASER EVADER
   3 .
  10 clear ;&(9)=50;BC=0;FC=124;&(0)=0;&(1)=0;D=1;G=3;H=3;M=40;N=-40;S=0;U=0;V=0;W=0;X=0;NT=0;&(19)=0
  12 for K=40to -14step -9;box -3,K,155,3,3;next K;CY=13;print "  L A S E R  E V A D E R 
  14 CY=-30;print "SINGLE left  J0YSTICK right  D0UBLE";box -3,-24,65,1,1;box -3,-36,65,1,1;NT=5
  16 if JX(1)=0MU=rnd (9)+75;goto 16
  18 NT=0;if JX(1)=1X=1
  20 clear ;FC=4;for A=30to -30step -15;for B=-30to 30step 60;for C=11to 7step -2;box B,A,C,C-2,3;next C;next B;next A
  25 for A=-30to 30step 15;box 0,A,53,3,3;box 0,A,45,3,2;next A
  30 box -60,29,35,11,3;box -60,29,33,9,3;for A=-70to -50step 10;box A,29,3,5,1;next A
  35 if Xbox 60,29,35,11,3;box 60,29,33,9,3;for A=50to 70step 10;box A,29,3,5,1;next A
  40 CX=-59;CY=15;print "S";print "   C";print "   0";print "   R";print "   E
  45 if X CX=62;CY=15;print "S";CX=62;print "C";CX=62;print "0";CX=62;print "R";CX=62;print "E
  47 goto 130
  50 NT=9;MU=80;NT=0;F=rnd (5)mul 15-45
  60 box 0,F,45,1,3;return 
  70 Y=-35;T=0;box 0,Y,3,5,1;if D=1&(2)=92;&(3)=92;&(9)=10;FC=12
  75 if D=2&(9)=30;FC=92;&(2)=172;&(3)=172
  77 if X CX=0;CY=15;print #0,D;for Z=0to 200;next Z;box 0,15,6,8,2
  80 T=T+1;&(19)=70-Y;Z=(TR(D)=1)mul 4;Y=Y-2;if Y+Z<-36Y=-35
  85 Y=Y+Z;if Y#-35box 0,Y+2-Z,3,5,2;box 0,Y,3,5,1
  90 P=(rnd (3)=1);if Pgosub 50;if F<Y+3if F>Y-3goto 150
 100 if Pgosub 60
 110 if Y<35goto 80
 120 &(19)=0;if D=1S=S+135-T
 125 if D=2U=U+135-T
 130 CX=-65;CY=-30;print #2,S
 132 if X CX=56;CY=-30;print #2,U
 135 &(20)=0;NT=7;for Z=1to 3;for Q=49to 53step 2;MU=Q;next Q;next Z;NT=15;MU=56;MU=48
 140 NT=0;for Z=0to 250;next Z;&(20)=9;&(21)=9;box 0,Y,3,5,2;box 0,F,45,3,2;goto 70
 150 for A=1to 15;for B=17to 23;&(B)=rnd (255);next B;next A;for A=17to 23;&(A)=0;next A;&(21)=255;&(23)=255
 160 if D=1if V=0N=N-10;for A=1to 5step 2;for B=1to 9;box N,29,A,A+2,3;next B;next A;box N,29,9,9,2
 165 if D=1G=G-1
 170 if D=2if W=0M=M+10;for A=1to 5step 2;for B=1to 9;box M,29,A,A+2,3;next B;next A;box M,29,9,9,2
 180 &(21)=0;&(23)=0;if D=2H=H-1
 190 if D=1if G>0goto 230
 200 if Xif D=2if H>0goto 230
 210 if D=1if G=0if S>399if V=0V=1;G=1;CX=-71;gosub 290;goto 130
 220 if D=2if H=0if U>399if W=0W=1;H=1;CX=49;gosub 290;goto 130
 230 if Xif H>0D=D+1;if D>2D=1
 240 if Xif H>0goto 130
 250 if G>0goto 130
 255 if Xif S<U CX=-71;gosub 300
 260 if Xif S>U CX=49;gosub 300
 270 &(9)=50;FC=211;box 0,0,36,27,1;box 0,0,32,23,2;CX=-9;CY=5;print "GAME",;CX=-9;CY=-5;print "OVER",;if TR(1)run 
 280 goto 270
 290 CY=29;print "B0NUS",;return 
 300 CY=29;print "L0SER",;return 
>:return 
